DECLARE @T TABLE
(
   id int,
   StartDate datetime,
   DEP char(1),
   EndDate datetime,
   row_num int PRIMARY KEY(id, row_num)
);

INSERT INTO @T(id, StartDate, DEP, EndDate, row_num)
   SELECT T1.id, T1.StartDate, T1.DEP, T1.EndDate,
          ROW_NUMBER() OVER(PARTITION BY T1.id ORDER BY T1.StartDate) AS row_num
     FROM @sampleData AS T1
    WHERE NOT EXISTS(SELECT T2.StartDate, T2.EndDate
                       FROM @sampleData AS T2
                      WHERE T2.id = T1.id
                        AND (T2.StartDate <> T1.StartDate
                             OR T2.EndDate <> T1.EndDate
                             OR T2.DEP <> T1.DEP)
                        AND T2.EndDate >= DATEADD(DAY, -14, T1.StartDate)
                        AND T2.EndDate <= T1.StartDate);

SELECT T1.id, T1.StartDate, ISNULL(T3.DEP, T1.DEP) AS DEP, ISNULL(T3.EndDate, T1.EndDate) AS EndDate
  FROM @T AS T1
       LEFT OUTER JOIN
       @T AS T2
       ON T2.id = T1.id
          AND T2.row_num = T1.row_num + 1
       OUTER APPLY
       (SELECT TOP(1) T3.DEP, T3.EndDate
          FROM @sampleData AS T3
         WHERE T3.id = T1.id
           AND T3.StartDate >= T1.StartDate
           AND T3.StartDate < T2.StartDate
        ORDER BY T3.EndDate DESC) AS T3