set nocount on
declare @t table (ProductId varchar(25),  Quantity int)
insert @t 
select 'P001', 1 union all
select 'P001.1' ,2 union all
select 'P001.2' ,4 union all
select 'P001.3' ,5 union all
select 'P002', 1 union all
select 'P002.1' ,6 union all
select 'P002.2' ,7 union all
select 'P002.3' ,9 union all
select 'P002.4' ,10 union all
select 'P002.5' ,11
set nocount off

--sequence the rows so we can recurse through them
;with t (prodRoot, productid, quantity, rn)
as
(
       select left(productID, 4), productID, Quantity, row_number() over (partition by left(productID, 4) order by productID)
       from   @t
)

--perform the PRODUCT aggregations
,t1 (prodRoot, productid, product, rn)
as
(
       select prodRoot, productID, Quantity, rn
       from   t
       where  rn = 1
       union all
       select t.prodRoot, t.productID, t1.product * t.Quantity, t.rn
       from   t 
       join   t1 
              on t1.prodRoot = t.prodRoot
              and t1.rn+1 = t.rn
)

--return the row with the final product
select prodRoot productID, null subProductID, max(product) quantity
from t1 
group by prodRoot

union all

--return the row of the last productID
select prodRoot, productid, null
from   (select seq = row_number() over (partition by prodRoot order by rn desc) 
              ,productID
              ,prodRoot
       from t1) d
where  seq = 1

--order it as you specified
order by 1, 3 desc

OUTPUT:

productID subProductID              quantity
--------- ------------------------- -----------
P001      NULL                      40
P001      P001.3                    NULL
P002      NULL                      41580
P002      P002.5                    NULL