SET QUOTED_IDENTIFIER ON
GO
SET ANSI_NULLS ON
GO

CREATE PROCEDURE sp_SMTPMail
	@ToAddress varchar(100),
	@FromAddress varchar(100),
	@Subject varchar(200),
	@Body varchar(8000)

AS	
SET NOCOUNT ON
DECLARE 
  @object int,
  @hr int,
  @property varchar(255),
  @return varchar(255),
  @src varchar(255), 
  @desc varchar(255),
  @Mailserver varchar(100)

SET @Mailserver = 'mymailserverip'

-- First, create the object.
EXEC @hr = sp_OACreate 'Persits.MailSender', @object OUT
IF @hr <> 0
  BEGIN
     -- Report any errors
     EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT 
     SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc
     GOTO END_ROUTINE
  END
ELSE
   -- An object is successfully created.
   BEGIN
      -- Set properties
      EXEC @hr = sp_OASetProperty @object, 'Host', @Mailserver
      IF @hr <> 0 GOTO CLEANUP
      EXEC @hr = sp_OASetProperty @object, 'From', @FromAddress
      IF @hr <> 0 GOTO CLEANUP
      EXEC @hr = sp_OASetProperty @object, 'Subject', @Subject
      IF @hr <> 0 GOTO CLEANUP
      EXEC @hr = sp_OASetProperty @object, 'Body', @Body
      IF @hr <> 0 GOTO CLEANUP

      EXEC @hr = sp_OAMethod @object, 'AddAddress', NULL, @ToAddress
      IF @hr <> 0 GOTO CLEANUP

      EXEC @hr = sp_OAMethod @object, 'Send', NULL
      GOTO CLEANUP

   END

CLEANUP:
   -- Check whether an error occurred.
   IF @hr <> 0
   BEGIN
      -- Report the error.
      EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT 
      SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc
   END

   -- Destroy the object.
   BEGIN
      EXEC @hr = sp_OADestroy @object
      -- Check if an error occurred.
      IF @hr <> 0 
      BEGIN
         -- Report the error.
         EXEC sp_OAGetErrorInfo @object, @src OUT, @desc OUT 
         SELECT hr=convert(varbinary(4),@hr), Source=@src, Description=@desc
      END
   END
END_ROUTINE:
RETURN


GO
SET QUOTED_IDENTIFIER OFF
GO
SET ANSI_NULLS ON 
GO