SELECT REPLICATE('-', LEVEL)

-- Note that if Sibbling pointers are NOT unique the sequence generated is indeterminate

DROP TABLE #MyTempTable
GO

CREATE TABLE #MyTempTable
(
	[T_MyID]	int,
	[T_MyParent]	int,
	[T_MySibbling]	int,
	[T_MyLevel]	int,
	[T_MySequence]	int,
	[T_MyPath]	varchar(7000)
)

-- Select all relevant original data into temporary table
INSERT INTO #MyTempTable
SELECT 
	[T_MyID]	= MyID,
	[T_MyParent]	= MyParent,
	[T_MySibbling]	= MySibbling,
	[T_MyLevel]	= NULL,
	[T_MySequence]	= NULL,
	[T_MyPath]	= NULL
FROM	dbo.MyTable

DECLARE	@intLoop	int,
	@intRowCount	int

-- Set LEVEL and SEQUENCE for Root Node
UPDATE	U
SET	[T_MyLevel] = 0,
	[T_MySequence] = 0,
	[T_MyPath] = '000000'	-- Max is 999 Levels and 999 Siblings, thus 6-digits
FROM	#MyTempTable U
WHERE	    T_MyParent IS NULL
	AND T_MySibbling IS NULL


-- Set SEQUENCE on all Eldest Siblings
UPDATE	U
SET	[T_MySequence] = 0
FROM	#MyTempTable U
WHERE	    T_MySibbling IS NULL

SELECT	@intLoop = 0,
	@intRowCount = 1	-- Force to run at least once

-- Set SEQUENCE on all rows
WHILE	(@intRowCount >= 1)
BEGIN
	IF @intLoop >= 999 RAISERROR ('Maximum Sibbling Sequence exceeded', 16, 1)

	-- Set all next-younger sibblings to the next-higher sequence
	UPDATE	C
	SET	[T_MySequence] = @intLoop + 1
	FROM	#MyTempTable C
		JOIN #MyTempTable P
			ON P.T_MyID = C.T_MySibbling
	WHERE	    C.T_MySequence IS NULL		-- Not-yet-done children ...
		AND P.T_MySequence IS NOT NULL	-- ... of already-done parents
		AND P.T_MySequence = @intLoop
	SELECT	@intRowCount = @@ROWCOUNT

-- SELECT [Level] = @intLoop, [Count] = @intRowCount	-- Debug

	SELECT @intLoop = @intLoop + 1	-- Proceed to next level
END

SELECT	@intLoop = 0,
	@intRowCount = 1	-- Force to run at least once

-- Set LEVEL on all rows
WHILE	(@intRowCount >= 1)
BEGIN
	IF @intLoop >= 999 RAISERROR ('Maximum Child Level exceeded', 16, 1)

	-- Set all children to the next-higher level
	UPDATE	C
	SET	T_MyLevel = @intLoop + 1,
		T_MyPath = P.T_MyPath + '/' 
			+ RIGHT('000'+CONVERT(varchar(20), @intLoop+1), 3) 
			+ RIGHT('000'+CONVERT(varchar(20), C.T_MySequence), 3)
	FROM	#MyTempTable C
		JOIN #MyTempTable P
			ON P.T_MyID = C.T_MyParent
	WHERE	    C.T_MyLevel IS NULL		-- Not-yet-done children ...
		AND P.T_MyLevel IS NOT NULL	-- ... of already-done parents
		AND P.T_MyLevel = @intLoop
	SELECT	@intRowCount = @@ROWCOUNT

-- SELECT [Level] = @intLoop, [Count] = @intRowCount	-- Debug

	SELECT @intLoop = @intLoop + 1	-- Proceed to next level
END


-- Set the Level, Sequence and Path on the original table
UPDATE	U
SET	MyLevel		= T.T_MyLevel,
	MySequence	= T.T_MySequence,
	MyPath		= T.T_MyPath
FROM	#MyTempTable T
	JOIN dbo.MyTable U
		ON U.MyID = T.T_MyID