create table #db (id int identity(0,1), name sysname)

insert	#db (name)
select	name
from	master..sysdatabases
--where	sid <> 0x01

create table #logins (name sysname, sid varbinary(85))

insert	#logins (name, sid)
select	name,
	sid
from	master..syslogins
where	sid <> 0x01

create table #users (dbname sysname null, loginsid varbinary(85), username sysname)

declare @id int,
	@sql varchar(1000),
	@dbname sysname

select	@id = max(id)
from	#db

while @id >= 0
	begin
		select	@dbname = name
		from	#db
		where	id = @id

		select @sql = 'insert #users (loginsid, username) select sid, name from ' + quotename(@dbname) + '..sysusers where sid is not null'
		exec (@sql)

		update	#users set dbname = @dbname where dbname is null

		select @id = @id - 1
	end

drop table #db

-- Logins that are connected to a database
select		#users.dbname 'Database name',
		#logins.name 'Login name'
from		#users
inner join	#logins on #logins.sid = #users.loginsid

-- Logins that are not connected to a database
select		#logins.name 'Login name'
from		#logins
left join	#users on #users.loginsid = #logins.sid
where		#users.loginsid is null

-- Users for a database that not have a login
select		#users.dbname 'Database name',
		#users.username 'User name'
from		#users
left join	#logins on #logins.sid = #users.loginsid
where		#logins.sid is null

drop table #logins
drop table #users