• Start a VNC/console session
• Start SQL Profiler
• File > New > Trace
• SQL Server = {local}
• Connect Using: Windows Authentication
• Click OK

• Specify: Trace Name
• Specify: Template Name
• Checkbox: Save to file {identify destination & filename}
• Set Max File Size: 10MB
• Checkbox: Enable File Rollover
• Commence Trace and lock console session.

create procedure sp_procoption
    @ProcName		nvarchar(776)
   ,@OptionName		varchar(35)
   ,@OptionValue	varchar(12)
as
	-- DECLARE VARIABLES
	DECLARE @tabid  int
			,@uid int
			,@intOptionValue  int
			,@dbname sysname

    -- DISALLOW USER TRANSACTION --
	Set nocount on
	set implicit_transactions off
	IF @@trancount > 0
	begin
		raiserror(15002,-1,-1,'sp_procoption')
		RETURN @@ERROR
	end

	-- VALIDATE OPTION NAME AND VALUE
	SELECT @intOptionValue =
		CASE WHEN (lower(@OptionValue) in ('1' ,'on' ,'yes' ,'true')) THEN 1
			WHEN (lower(@OptionValue) in ('0' ,'off' ,'no' ,'false')) THEN 0
		ELSE NULL END
	IF @intOptionValue IS NULL OR @OptionName IS NULL OR lower(@OptionName) <> 'startup'
	BEGIN
		raiserror(15600,-1,-1, 'sp_procoption')
		RETURN @@ERROR
	END

	-- MUST BE sysadmin (Startup-procs run as sysadmin) --
	IF is_srvrolemember('sysadmin') = 0
	BEGIN
		raiserror(15247,-1,-1)
		RETURN @@ERROR
	END

	-- RESOLVE GIVEN OBJECT NAME --
	SELECT @tabid = id, @uid = uid FROM sysobjects
		WHERE id = OBJECT_ID(@ProcName, 'local') AND xtype IN ('X','P')

	-- VALID OBJECT IN DATABASE? --
	IF @tabid IS NULL
	BEGIN
		SELECT @dbname = db_name()
		raiserror(15009,-1,-1 ,@ProcName, @dbname)
		RETURN @@ERROR
	END

	-- STARTUP PROC MUST BE OWNED BY DBO IN MASTER --
	IF (db_id() <> 1 OR @uid <> 1)
	BEGIN
		raiserror(15398,-1,-1)
		RETURN @@ERROR
	END

	-- PROC CANNOT HAVE PARAMETERS --
	IF EXISTS ( SELECT * FROM syscolumns WHERE id = @tabid )
	BEGIN
		raiserror(15399,-1, -1)
		RETURN @@ERROR
	END

	-- Do the work
	BEGIN TRAN
	DBCC LockObjectSchema(@ProcName)
	UPDATE sysobjects SET status = (status & ~2) | (2 * @intOptionValue) WHERE id = @tabid

	-- Set Config option for startup procs
	UPDATE master.dbo.sysconfigures SET value =
			CASE WHEN EXISTS (SELECT * FROM sysobjects WHERE xtype IN ('X','P')
				AND ObjectProperty(id, 'ExecIsStartup') = 1)
			THEN 1 ELSE 0 END
		WHERE config = 1547

	-- If no error, commit and reconfigure
	IF (@@error <> 0)
	BEGIN
		ROLLBACK TRAN
		RETURN 1
	END
	COMMIT TRAN
	RECONFIGURE WITH OVERRIDE

	-- RETURN SUCCESS
	RETURN 0 -- sp_procoption

GO