create function NormalizeXTabSQL(@TableName varchar(500), @ColumnIncrement int, @StartColumn int, @EndColumn int)
returns varchar(4000)
as
begin
--NormalizeXTab
--blindman, 2/4/2005
--Returns a SQL UNION statement that converts repeating
--column groups in a table into normalized individual records.

--Test parameters
-- declare @TableName varchar(500)
-- declare @ColumnIncrement int
-- declare @StartColumn int
-- declare @EndColumn int
-- set	@TableName = 'LimsImportStaging' --Name of your target table
-- set	@ColumnIncrement = 3  --Number of columns to return for each statement
-- set	@StartColumn = 2
-- set	@EndColumn = 16

declare	@ColumnString varchar(500)
declare	@ColumnCounter int
declare	@SQLString varchar(4000)

set     @ColumnCounter = isnull(@StartColumn, 1) - 1

set     @EndColumn = isnull(@EndColumn,
        (select	count(*)
        from	sysobjects
                inner join syscolumns on sysobjects.id = syscolumns.id
        where	sysobjects.name = @TableName))

while   @ColumnCounter < @EndColumn
begin
        set	@ColumnString = null
        set	@ColumnCounter = @ColumnCounter + @ColumnIncrement

        select	@ColumnString = isnull(@ColumnString + ', ', '') + syscolumns.name
        from	sysobjects
                inner join syscolumns on sysobjects.id = syscolumns.id
        where	sysobjects.name = @TableName
                and colid > @ColumnCounter - @ColumnIncrement
                and colid <= @ColumnCounter
                and colid <= @EndColumn
        order by colid
	
        set     @SQLString = isnull(@SQLString + char(13) + 'UNION' + char(13), '') + 'select ' + @ColumnString  + ' from ' + @TableName
end

return	@SQLString

end