/*
ID Task Name ParentID Cost
---- --------------------- --------- ----------- 
1, Design Activities, null, 0
2, Write Specs, 1, 0
3, Write UI Spec, 2, 45
4, Write Data Spec, 2, 15
5, Build Prototypes, 1, 0
6, Build Screen Mockkups, 5, 20
7, Build Widget Prototype, 5, 15

Notice how actual values exist ONLY at the lowest level

I want to return data like the following: 

ID Task Name ParentID Cost
---- --------------------- --------- ----------- 
1, Design Activities, null, 95
2, Write Specs, 1, 60
3, Write UI Spec, 2, 45
4, Write Data Spec, 2, 15
5, Build Prototypes, 1, 35
6, Build Screen Mockkups, 5, 20
7, Build Widget Prototype, 5, 15 
*/

DECLARE @foo TABLE (
	[ID] INT
	, [Task Name] NVARCHAR(255)
	, [ParentId] INT
	, [cost] MONEY
	)

INSERT @foo
      SELECT 1, 'Design Activities', null, 0
UNION SELECT 2, 'Write Specs', 1, 0
UNION SELECT 3, 'Write UI Spec', 2, 45
UNION SELECT 4, 'Write Data Spec', 2, 15
UNION SELECT 5, 'Build Prototypes', 1, 0
UNION SELECT 6, 'Build Screen Mockkups', 5, 20
UNION SELECT 7, 'Build Widget Prototype', 5, 15

; WITH cte AS (
SELECT
	[ID] AS [Start_Id]
	, [parentId] AS [Start_Parent_Id]
	, [ID]
	, [Task Name]
	, [ParentId]
	, [cost]
FROM
	@foo f1
UNION ALL SELECT
	f1.[start_Id]
	, f1.[Start_Parent_Id]
	, f2.[ID]
	, f1.[task Name]
	, f2.[parentId]
	, f2.[cost]
FROM
	@foo f2
	JOIN cte f1 ON f1.[Id] = f2.[parentId]
	)
SELECT
	[start_Id]
	, [task Name]
	, [start_parent_Id]
	, SUM([cost])
FROM
	cte
GROUP BY
	[start_Id]
	, [task Name]
	, [start_parent_Id]
OPTION (MAXRECURSION 0)