use tempdb
go
create table [fields] (id int, field varchar(2000))
go
create table [products] (productID int, productDesc varchar(200))
go

insert [products]
select 1, 'Board Analyst' union all
select 2, 'Chartmaker' union all
select 3, 'GIST' union all
select 4, 'Interlocks' union all
select 5, 'Networking'

insert [Fields]
select 1, 'Board Analyst' union all
select 2, 'Board Analyst | Chartmaker' union all
select 3, 'Board Analyst | Chartmaker | GIST' union all
select 4, 'Networking Tool | GIST'

go

create function dbo.splitFields (@f varchar(2000))
returns @t table (fld varchar(200))
as
begin
       declare @i int
       set @f = '|' + replace(replace(@f,' |', '|'),'| ', '|') + '|'
       select @i = charindex('|', @f, 1)
       while @i > 0 and @i < len(@f)
       begin
              insert @t
              select substring(@f, @i+1, charindex('|', @f, @i+1)-@i-1 )
              set @i = charindex('|', @f, @i+1)
       end
       return 
end
go

select row_number() over (order by fs.id, p.productid) as rowID
       ,fs.id, p.productid
from [fields] fs
cross apply ( select fld from dbo.splitFields(fs.field) ) f
inner join [products] p
       on p.productDesc = f.fld
       

go
drop function dbo.splitFields
drop table [fields]
drop table [products]
go

OUTPUT:
rowID                id          productid
-------------------- ----------- -----------
1                    1           1
2                    2           1
3                    2           2
4                    3           1
5                    3           2
6                    3           3
7                    4           3