Public Function LinkToCSVFile(strFileName As String, _
                               strLinkName As String) As Boolean
    
    'PURPOSE: Creates an attached table from a CSV text file.
    'Returns True if error, False if no error
    
    Dim db  As Database
    Dim tdf As TableDef
    Dim fs  As New FileSystemObject
    Echo True, "Linking to file """ & strFileName & """"
    LinkToCSVFile = False 'No error condition
    If Not fs.FileExists(FileSpec:=strFileName) Then
        Err.Raise vbObjectError + 3, , "The file does not exist."
    End If
    
        Set db = CurrentDb()
        With db
            On Error Resume Next
                If .TableDefs(strLinkName).Name = strLinkName Then
                    'A quick test to see if the table exists
                    .Execute "DROP TABLE " & strLinkName
                    .TableDefs.Refresh
                End If
            On Error GoTo ErrHandler
        End With
    
    Set tdf = db.CreateTableDef(strLinkName)
    With tdf
    .Connect = "Text;DSN=" & strLinkName _
             & " Link Specification;FMT=Fixed;HDR=NO;IMEX=2;" _
             & "DATABASE=" & fs.GetParentFolderName(Path:=strFileName) & ";"
                 
        .Name = strLinkName
        .SourceTableName = fs.GetFileName(Path:=strFileName)
    End With
    
    On Error Resume Next
        DoCmd.TransferText      'Workaround for Access97 bug -- _
                                 If this is not done, the _
                                 "MaxData Link Specification" IMEX spec _
                                 may or may not be visible to Access.
    On Error GoTo ErrHandler
    
    With db.TableDefs
        .Append tdf
        .Refresh
    End With
    
ExitHere:
    Echo True, ""
    Set tdf = Nothing
    Set db = Nothing
    Set fs = Nothing
    Exit Function
    
ErrHandler:
    Select Case MsgBox(Err.Description, vbAbortRetryIgnore)
    Case vbAbort
        LinkToCSVFile = True 'Error condition
        Resume ExitHere
    Case vbRetry
        Resume
    Case vbIgnore
        Resume Next
    End Select
End Function